Måste jag köra mitt bash-script varje minut i crontab för att träffa rätt?

Soluppgång och -nedgång kan man beräkna hjälpligt själv, utan att behöva gå över internet och Yahoo. "Själv" syftar här på att någon annan redan har gjort det; exempelvis i Perlmodulen DateTime::Astro::Sunrise.

1. Installera paketet libdatetime-astro-sunrise-perl.

2. Spara nedanstående snabbsnickrade skript (varning för undermålig testning) som ~/bin/atsunrisesunset.pl:

   Visa innehåll

   #!/usr/bin/env perl
   use strict;
   use warnings;
   
   use DateTime::TimeZone;
   use DateTime::Astro::Sunrise;
   use File::Basename;
   use Scalar::Util qw/looks_like_number/;
   
   my $at = '/usr/bin/at';
   my $time_format = '%H:%M %Y-%m-%d';
   
   sub usage {
       my $script_name = basename($0);
       print STDERR <<"    USAGE";
   Schedule jobs with $at at sunrise and sunset of the current day.
   
   usage: $script_name LATITUDE LONGITUDE SUNRISE_JOB_FILE SUNSET_JOB_FILE
          $script_name LATITUDE LONGITUDE
   
   The first form schedules the given jobs at sunrise and sunset of current day.
   The second form prints a debug message with the times that would be used.
   
   LATITUDE and LONGITUDE are decimal degree representations of latitude and
   longitude of where wanted sunrise and sunset times are to be calculated.
   
   SUNRISE_JOB_FILE and SUNSET_JOB_FILE are job files suited for use with `at`.
       USAGE
       exit 1;
   }
   
   sub debug {
       my ($sunrise_time, $sunset_time) = sunrise_and_sunset_times(@_);
       print <<"    DEBUG";
   Debug info
   ----------
   Calculated sunrise for today: $sunrise_time
   Calculated sunset  for today: $sunset_time
       DEBUG
       exit;
   }
   
   sub sunrise_and_sunset_times {
       my ($latitude, $longitude) = @_;
   
       unless (looks_like_number($latitude) && looks_like_number($longitude)) {
           usage();
       }
   
       my $dt = DateTime->now;
       my $tz = DateTime::TimeZone->new(name => 'local');
       $dt->set_time_zone($tz);
   
       my $dt_a_s = DateTime::Astro::Sunrise->new($longitude, $latitude);
       my @times = $dt_a_s->sunrise($dt);
   
       foreach my $time (@times) { $time->set_time_zone($tz) }
   
       return @times;
   }
   
   sub at_schedule {
       my ($time, $job_file) = @_;
       system($at, $time->strftime($time_format), '-f', $job_file);
   }
   
   sub parse_cli {
       my $argc = $#ARGV + 1;
       if    ($argc == 2) { debug(@ARGV) }
       elsif ($argc == 4) { return @ARGV }
       else               { usage() }
   }
   
   sub main {
       my ($longitude, $latitude, $sunrise_jobs, $sunset_jobs) = parse_cli();
       my ($sunrise, $sunset) = sunrise_and_sunset_times($latitude, $longitude);
   
       foreach my $at_cmd ([$sunrise, $sunrise_jobs], [$sunset, $sunset_jobs]) {
           at_schedule(@$at_cmd);
       }
   }
   
   main();

   Dold text

3. Gör skriptet exekverbart:

   chmod +x ~/bin/atsunrisesunset.pl

   Ifall du kör skriptet med två parametrar (latitud och longitud) så skriver det ut de tider som räknats ut för den aktuella dagen, vilket kan vara bra för en rimlighetskontroll. Exempel för Stockholm:

   $ ~/bin/atsunrisesunset.pl 59.3294 18.0686
   Debug info
   ----------
   Calculated sunrise for today: 2015-10-15T07:22:00
   Calculated sunset  for today: 2015-10-15T17:44:00

   Körs skriptet med fyra parametrar som beskriver latitud, longitud, samt jobbfiler för soluppgång respektive -nedgång så köas dessa jobbfiler med at vid motsvarande tider. Enklast körs skriptet strax efter midnatt.

4. Skapa dina jobbfiler /path/to/sunrise_job_file respektive /path/to/sunset_job_file (med sökvägar enligt eget tycke). Notera att dina "jobbfiler" bara ska innehålla namnen på de skript du faktiskt vill köra, snarare än skriptlogiken i sig. Är det triviala skript så går det visserligen att köra dem direkt i denna fil, "men det är inte rätt" . Jag skrev lite längre om detta en annan gång på forumet.

5. Kör följande i din användares crontab:

   5 0 * * * /home/användare/bin/atsunrisesunset.pl 59.3294 18.0686 /path/to/sunrise_job_file /path/to_sunset_job_file 2>/dev/null

   Fem minuter över midnatt varje dag så bör då cron se till att dina at-körningar adderas.

Spontana förbättringsidéer som lämnas som övningar åt läsaren;

• Vettig felrapportering ifall at-körningarna misslyckas.

• Varningstext för folk boende norr/söder om respektive polcirkel…