Automatiskt reverse ssh tunnel script

#!/usr/bin/expect -f

if {$argc != 7} {
  puts "Usage: ./sshrevtun <localhost> <localport> <user> <host> <remoteport> <password> <remotebindport>"
  exit 0
}

proc exit_timeout {} {
  puts "Error: timeout"
  exit 1
}

proc exit_unexpected {data} {
  set data [string trim $data]
  puts "Error: unexpected response: $data"
  exit 1
}

trap {
  if {$thispid != 0} {
    wait
    exit 0
  }
} SIGCHLD

log_user 0

set connectcatch "connected"

set localhost [lindex $argv 0]
set localport [lindex $argv 1]
set user [lindex $argv 2]
set host [lindex $argv 3]
set remoteport [lindex $argv 4]
set password [lindex $argv 5]
set remotebindport [lindex $argv 6]

set thispid [fork]

if {$thispid != 0} {
  sleep 20
} else {
  spawn ssh -o "StrictHostKeyChecking no" -f -R $remotebindport:$localhost:$localport $user@$host -p $remoteport "echo $connectcatch && sleep 3600"
  expect {
    timeout exit_timeout
    eof {exit_unexpected $expect_out(buffer)}
    "assword:"
  }
  send $password\n
  expect {
    "assword:" {exit_unexpected $expect_out(buffer)}
    "ermission" {exit_unexpected $expect_out(buffer)}
    eof {exit_unexpected $expect_out(buffer)}
    timeout exit_timeout
    $connectcatch
  }
  puts "Success! Tunnel will stay open for 1 hour."
  disconnect
}